ARDevMob

// SGH2010
// This is ARQanoide the AR Arkanoid Clone

/**
 * a arkanoid clone by guru
 * adjusted by SidGabriel to use a webcam and a colorful object of your choice. 
 * Sid's additions marked SGH
 */

//SGH
import processing.video.*;
// Variable for capture device
Capture video; 
// A variable for the color we are searching for.
color trackColor; 
// variables for toggles
boolean showImage;
boolean acquireColor;
boolean testColor;
// Global tracking coordinates
int wrX;
int wrY;
PFont myFont;
///sgh

int px, py;
int vx, vy;

boolean paused = true;
boolean done = true;
int[][] stones; 

void setup() {
  size(300,300);
  noCursor();
  px = width/2;
  py = height/2;

  vx = int(random( 10, 18 ));
  vy = 20;

  stones = new int[7][4];
  for( int x = 0; x < 7; x++) {
    for( int y = 0; y < 4; y++ ) {
      stones[x][y] = y + 1;
    }
  }  

  //SGH
  myFont = createFont("Arial", 18);
  textFont(myFont);
  video = new Capture(this,width,height,15);
  // Start off tracking
  trackColor = color(255,255,255);
  smooth();
  ///SGH
}

void draw() {
  //background(50);
  //SGH Get Camera Controller Info
  // Capture the video
  if (video.available()) {
    video.read();
  }
  video.loadPixels();
  image(video,0,0);
  ///SGH
  stroke(255);
  strokeWeight(2);

  // update postion of the ball 
  if (!paused) update();

  // draw all stones that are not removed yet
  // check if all are gone
  done = true;
  for( int x = 0; x < 7; x++) {
    for( int y = 0; y < 4; y++ ) {
      if ( stones[x][y] > 0 ) {
        done = false;
        // fill( 128 + 10 * stones[x][y] );
        rect( 10 + x * 40, 10 + y * 20, 40, 20 ); 
      }
    }
  }

  // no stone remaining - display yippie message
  if ( done ) {
    paused = true;
    fill(255);
    textSize( 48 );
    text( "JIPPIE!", 50, 200 );
  }

  // display text if paused
  if ( paused ) {
    textSize( 16 );
    fill(128);
    text( "pres 's' to start/stop 't' to train a controller", 10, 270 );
  }

  fill(128);
  // draw ball
  ellipse(px,py,20,20);

  // Before we begin searching, the "world record" for closest color is set to a high number that is easy for the first pixel to beat.
  float worldRecord = 1500; 

  // XY coordinate of closest color
  int closestX = 0;
  int closestY = 0;

  // Begin loop to walk through every pixel
  for (int x = 0; x < video.width; x ++ ) {
    for (int y = 0; y < video.height; y ++ ) {
      int loc = x + y*video.width;
      // What is current color
      color currentColor = video.pixels[loc];
      float r1 = red(currentColor);
      float g1 = green(currentColor);
      float b1 = blue(currentColor);
      float r2 = red(trackColor);
      float g2 = green(trackColor);
      float b2 = blue(trackColor);

      // Using euclidean distance to compare colors
      float d = dist(r1,g1,b1,r2,g2,b2); // We are using the dist( ) function to compare the current color with the color we are tracking.

      // If current color is more similar to tracked color than
      // closest color, save current location and current difference
      if (d < worldRecord) {
        worldRecord = d;
        closestX = x;
        closestY = y;
      }
    }
  }

  // We only consider the color found if its color distance is less than 10. 
  // This threshold of 10 is arbitrary and you can adjust this number depending on how accurate you require the tracking to be.
  //  if (worldRecord < 10) { 
  //    // Draw a circle at the tracked pixel
  //    fill(trackColor);
  //    strokeWeight(4.0);
  //    stroke(0);
  //    ellipse(closestX,closestY,16,16);
  //  }
  if (worldRecord < 20) { 
    // Draw a circle at the tracked pixel
    //fill(trackColor);
    //strokeWeight(4.0);
    //stroke(255);
    wrX = closestX;
    wrY = closestY;
    // draw paddle
    fill(trackColor);
    rect( closestX - 35, 270, 70, 20 );
  } 
  else {
    fill(128);
    rect( 150 - 35, 270, 70, 20 );
  }
  // ready target mode
  if(showImage) {
    set(0, height - video.height, video);
    fill(trackColor);
    stroke(trackColor);
    ellipse(mouseX,mouseY,8,8);
    textSize( 16 );
    fill(128);
    text( "'a' to acquire a color", 10, 260 );
    text( "'c' to test control color", 10, 250 );

  }
  if(acquireColor) {
    fill(trackColor);
    ellipse(closestX,closestY,16,16);
    int loc = mouseX + mouseY*video.width;
    trackColor = video.pixels[loc];
    textSize( 16 );
    fill(128);
    text( "Acqire an object by moving the mouse over it and pres 'a'", 10, 240 );
  }
  if(testColor) {
    fill(trackColor);
    ellipse(closestX,closestY,16,16);
    text( "confirm read 'c' when done", 10, 240 );
  }
}

void update() {
  // check if ball dropped out of the lower border
  if ( py + vy > height - 10 ) {
    px = width/2;
    py = height/2;
    vx = int(random( 0, 16 ));
    vy = 2;
    paused = true;
  }


  // check if the ball hits a block
  for( int x = 0; x < 7; x++) {
    for( int y = 0; y < 4; y++ ) {
      if ( stones[x][y] > 0 ) {
        if ( px + vx + 10 > 10 + x * 40 && px + vx - 10 < 10 + x * 40 + 40 &&
          py + vy + 10 > 10 + y * 20 && py + vy - 10 < 10 + y * 20 + 20 ) {
          stones[x][y] = 0;

          // change the velocity in y direction if the block has been hit 
          // on the bottom or on the top 
          if ( px + 10 > 10 + x * 40 && px - 10 < 10 + x * 40 + 40 ) vy = -vy;
          // change the velocity in the x direction if the block has been hit on the side
          if ( py + 10 > 10 + y * 20 && py - 10 < 10 + y * 20 + 20 ) vx = -vx; 
        }
      }
    }
  }

  // change the direction if the ball hits a wall
  if (px + vx  < 10 || px + vx > width - 10) {
    vx = -vx;
  }

  if (py + vy  < 10 || py + vy > height - 10) {
    vy = -vy;
  }

  // check if the paddle was hit
  if ( py + vy >= 266  && px >= wrX - 35 && px <= wrX +35 ) {
    vy = -vy;
    vx = int(map( px - wrX, -35, 35, -8, 8 ));
  }  

  // calculate new postion
  px += vx;
  py += vy;
}

void mousePressed() {
  if (done) {
    for( int x = 0; x < 7; x++) {
      for( int y = 0; y < 4; y++ ) {
        stones[x][y] = y + 1;
      }
    }
    done = false;
    px = width/2;
    py = height/2;
    vx = int(random( -8, 8 ));
    vy = -2;
  }

}
//SGH Target Mode Toggle
// t = show camera to target color
// a = acquire the color directly under the mouse + show all other pixels with the color
// c = confirm camera color tracking by tagging all pixels of the target range
// s = start or stop the game 

public void keyPressed(){
  switch (key){
  case 't': 
    showImage = !showImage; 
    break;
  case 'a': 
    acquireColor = !acquireColor; 
    break;
  case 'c': 
    testColor = !testColor; 
    break;
  case 's': 
    paused = !paused;
  }
}


// SGH2010